Buffextras/mIRC

mIRC Script

This mIRC script is useful for parsing the events saved within the buffextras module.

Note: Requires at least mIRC v7.33 and ZNC 1.7.0.

on ^*:TEXT:*:#: {
  if ($nick == *buffextras) {
    var %nick = $gettok($1,1,$asc(!))
    
    if ($3 == MODE:)       echo $color(mode) -t $+ $msgstamp $chan * %nick sets mode: $4-
    elseif ($2 == JOINED)  echo $color(join) -t $+ $msgstamp $chan * %nick ( $+ $gettok($1, 2, $asc(!)) $+ ) has joined $chan
    elseif ($2 == QUIT:)    echo $color(quit) -t $+ $msgstamp $chan * %nick ( $+ $gettok($1, 2, $asc(!)) $+ ) Quit ( $+ $3- $+ )
    elseif ($2 == PARTED:)  echo $color(part) -t $+ $msgstamp $chan * %nick ( $+ $gettok($1, 2, $asc(!)) $+ ) has left $chan
    elseif (($2 == IS) && ($3 == NOW)) echo $color(nick) -t $+ $msgstamp $chan * %nick is now known as $6
    elseif ($2 == KICKED)  echo $color(kick) -t $+ $msgstamp $chan * $3 was kicked by $gettok($1,1,$asc(!)) ( $+ $6- $+ )
    elseif ($2 == CHANGED) echo $color(join) -t $+ $msgstamp $chan * %nick changes topic to ' $+ $6- $+ '
    else                   echo $color(erro) -t $+ $msgstamp $chan *** UNHANDLED LINE < $+ $1- $+ >
    halt
  }
}